home *** CD-ROM | disk | FTP | other *** search
/ Freelog 125 / Freelog_MarsAvril2015_No125.iso / ViePratique / gnucash / gnucash-2.6.5-setup.exe / {app} / bin / gnc-fq-helper < prev    next >
Text File  |  2014-12-19  |  13KB  |  452 lines
  1. #!/c/gcdev/gnucash-2.6.5a/mingw/msys/1.0/bin/perl -w
  2. ######################################################################
  3. ### gnc-fq-helper - present a scheme interface to Finance::Quote
  4. ### Copyright 2001 Rob Browning <rlb@cs.utexas.edu>
  5. ### 
  6. ### This program is free software; you can redistribute it and/or    
  7. ### modify it under the terms of the GNU General Public License as   
  8. ### published by the Free Software Foundation; either version 2 of   
  9. ### the License, or (at your option) any later version.              
  10. ###                                                                  
  11. ### This program is distributed in the hope that it will be useful,  
  12. ### but WITHOUT ANY WARRANTY; without even the implied warranty of   
  13. ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the    
  14. ### GNU General Public License for more details.                     
  15. ###                                                                  
  16. ### You should have received a copy of the GNU General Public License
  17. ### along with this program# if not, contact:
  18. ###
  19. ### Free Software Foundation           Voice:  +1-617-542-5942
  20. ### 51 Franklin Street, Fifth Floor    Fax:    +1-617-542-2652
  21. ### Boston, MA  02110-1301,  USA       gnu@gnu.org
  22. ######################################################################
  23.  
  24. use strict;
  25. use English;
  26. use FileHandle;
  27.  
  28. # The following include is needed for the ParseDateString function.
  29. # This should eventually be replaced with a requirement for F::Q
  30. # version 1.11 (or better) and the use of the 'isodate' field to
  31. # handle the date part of the conversion.  Still need a method to
  32. # handle the time conversion.
  33. use Date::Manip;
  34.  
  35. =head1 NAME
  36.  
  37. gnc-fq-helper  -  allows gnucash to communicate with Finance::Quote
  38.                   over pipes from guile. The requests and responses
  39.                   are scheme forms.
  40.  
  41. =head1 SYNOPSIS
  42.  
  43. gnc-fq-helper
  44.  
  45. =head1 DESCRIPTION
  46.  
  47. Input: (on standard input - one entry per line and one line per
  48. entry, and double quotes must only be delimiters, not string
  49. content -- remember, we don't have a real scheme parser on the perl
  50. side :>).
  51.  
  52. (<method-name> symbol symbol symbol ...)
  53.  
  54. where <method-name> indicates the desired Finance::Quote method.
  55. The currently recognized subset is yahoo, yahoo_europe,
  56. fidelity_direct, troweprice_direct, vanguard, asx, tiaacref,
  57. and currency.
  58.  
  59. For currency quotes, the symbols alternate between the 'from'
  60. and 'to' currencies.
  61.  
  62. For example:
  63.  
  64. (yahoo "IBM" "LNUX")
  65. (fidelity_direct "FBIOX" "FSELX")
  66. (currency "USD" "AUD")
  67.  
  68. Output (on standard output, one output form per input line):
  69.  
  70. Schemified version of gnc-fq's output, basically an alist of
  71. alists, as in the example below.  Right now, only the fields that
  72. this script knows about (and knows how to convert to scheme) are
  73. returned, so the conversion function will have to be updated
  74. whenever Finance::Quote changes.  Currently you'll get symbol,
  75. gnc:time-no-zone, and currency, and either last, nav, or price.
  76. Fields with gnc: prefixes are non-Finance::Quote fields.
  77. gnc:time-no-zone is returned as a string of the form "YYYY-MM-DD
  78. HH:MM:SS", basically the unmolested (and underspecified) output of
  79. the quote source.  It's up to you to know what it's proper timezone
  80. really is.  i.e. if you know the time was in America/Chicago, you'll
  81. need to convert it to that.
  82.  
  83. For example:
  84.  
  85.  $ echo '(yahoo "CSCO" "JDSU" "^IXIC")' | ./gnc-fq-helper
  86. (("CSCO" (symbol . "CSCO")
  87.          (gnc:time-no-zone . "2001-03-13 19:27:00")
  88.          (last . 20.375)
  89.          (currency . "USD"))
  90.  ("JDSU" (symbol . "JDSU")
  91.          (gnc:time-no-zone . "2001-03-13 19:27:00")
  92.          (last . 23.5625)
  93.          (currency . "USD"))
  94. ("^IXIC" (symbol . ^IXIC)
  95.          (gnc:time-no-zone . 2002-12-04 17:16:00)
  96.          (last . 1430.35)
  97.          (currency . failed-conversion)))
  98.  
  99. On error, the overall result may be #f, or on individual errors, the
  100. list sub-item for a given symbol may be #f, like this:
  101.  
  102.  $ echo '(yahoo "CSCO" "JDSU")' | ./gnc-fq-helper
  103. (#f
  104.  ("JDSU" (symbol . "JDSU")
  105.          (gnc:time-no-zone . "2001-03-13 19:27:00")
  106.          (last . 23.5625)
  107.          (currency . "USD")))
  108.  
  109. further, errors may be stored with each quote as indicated in
  110. Finance::Quote, and whenever the conversion to scheme data fails,
  111. the field will have the value 'failed-conversion, and accordingly
  112. this symbol will never be a legitimate conversion.
  113.  
  114. Exit status
  115.  
  116. 0 - success
  117. non-zero - failure
  118.  
  119. =cut
  120.  
  121. # The methods we know about.  For now we assume they all have the same
  122. # signature so this works OK.
  123.  
  124. sub check_modules {
  125.   my @modules = qw(Finance::Quote LWP HTTP::Request::Common HTML::TableExtract Crypt::SSLeay);
  126.   my @missing;
  127.  
  128.   foreach my $mod (@modules) {
  129.     if (eval "require $mod") {
  130.       $mod->import();
  131.     }
  132.     else {
  133.       push (@missing, $mod);
  134.     }
  135.   }
  136.  
  137.   return unless @missing;
  138.  
  139.   print STDERR "\n";
  140.   print STDERR "You need to install the following Perl modules:\n";
  141.   foreach my $mod (@missing) {
  142.     print STDERR "  ".$mod."\n";
  143.   }
  144.  
  145.   print STDERR "\n";
  146.   print STDERR "Use your system's package manager to install them,\n";
  147.   print STDERR "or run 'gnc-fq-update' as root.\n";
  148.  
  149.   print "missing-lib";
  150.  
  151.   exit 1;
  152. }
  153.  
  154. sub schemify_string {
  155.   my($str) = @_;
  156.  
  157.   if(!$str) { return "failed-conversion"; }
  158.  
  159.   # FIXME: Is this safe?  Can we just double all backslashes and backslash
  160.   # escape all double quotes and get the right answer?
  161.  
  162.   # double all backslashes.
  163.   my $bs = "\\";
  164.   $str =~ s/$bs$bs/$bs$bs/gmo;
  165.  
  166.   # escape all double quotes.
  167.   # Have to do this because the perl-mode parser freaks out otherwise.
  168.   my $dq = '"';
  169.   $str =~ s/$dq/$bs$dq/gmo;
  170.   return '"' . $str . '"';
  171. }
  172.  
  173. sub schemify_boolean {
  174.   my($bool) = @_;
  175.  
  176.   if($bool) {
  177.     return "#t";
  178.   } else {
  179.     return "#f";
  180.   }
  181. }
  182.  
  183. sub schemify_num {
  184.   my($numstr) = @_;
  185.   # This is for normal numbers, not the funny ones like "2.346B".
  186.   # For now we don't need to do anything.
  187.  
  188.   if(!$numstr) { return "failed-conversion"; }
  189.  
  190.   if($numstr =~ /^\s*(\d+(\.\d+)?)$/o) {
  191.     return $1;
  192.   } else {
  193.     return "failed-conversion";
  194.   }
  195. }
  196.  
  197. sub schemify_date {
  198.   # return the date in epoch seconds.
  199.   my ($datestr) = @_;
  200.  
  201.   my $date = ParseDate($datestr);
  202.   my $result = UnixDate($date, "%s");
  203.   if($result !~ /^(\+|-)?\d+$/) {
  204.     $result = "failed-conversion";
  205.   }
  206.   return("$result");
  207. }
  208.  
  209. # sub schemify_range {
  210. #   #convert range in form ``num1 - num2'' to ``(num1 num2)''.
  211. # }
  212.  
  213. sub get_quote_time {
  214.   # return the date.
  215.   my ($item, $quotehash) = @_;
  216.  
  217.   my $datestr = $$quotehash{$item, 'date'};
  218.   my $timestr = $$quotehash{$item, 'time'};
  219.  
  220.   if(!$datestr) {
  221.     return undef;
  222.   }
  223.  
  224.   my $parsestr = $datestr;
  225.   if(!$timestr) {
  226.     #fix date handling for quotes with no time. 
  227.     #Keeps gnucash from getting date wrong in west longitude places.
  228.     $parsestr .= " 12:00:00"
  229.   } else {
  230.     $parsestr .= " $timestr";
  231.   }
  232.  
  233.   $parsestr = ParseDateString($parsestr);
  234.  
  235.   my $result = UnixDate($parsestr, "\"%Y-%m-%d %H:%M:%S\"");
  236.   if(!$result) {
  237.     # Fix date handling for quotes with no date: assume local date
  238.     (my $second,my $minute,my $hour,my $dayofmonth,my $month,my $year,my $dayofweek,my $dayofyear,my $daylightsaving) = localtime();
  239. #    $result = "\"".sprintf("%04d-%02d-%02d%02d:%02d:%02d",($year+1900),++$month,$dayOfMonth,$hour,$minute,$second)."\"";
  240.     $result = "\"" . sprintf("%04d-%02d-%02d", ($year+1900), ++$month, $dayofmonth) . " 12:00:00\"";
  241.   }
  242.   if($result !~ /^\"\d\d\d\d-\d\d-\d\d \d\d:\d\d:\d\d\"$/) {
  243.     $result = "failed-conversion";
  244.   }
  245.   return $result;
  246. }
  247.  
  248. sub schemify_quote {
  249.   my($itemname, $quotehash, $indentlevel) = @_;
  250.   my $scmname = schemify_string($itemname);
  251.   my $quotedata = "";
  252.   my $field;
  253.   my $data;
  254.  
  255.   if (!$$quotehash{$itemname, "success"}) {
  256.     return schemify_boolean(0);
  257.   }
  258.  
  259.   $field = 'symbol';
  260.   if (($$quotehash{$itemname, $field})) {
  261.     $data = schemify_string($$quotehash{$itemname, $field});
  262.   } else {
  263.     # VWD and a few others don't set the symbol field
  264.     $data = schemify_string($itemname);
  265.   }
  266.   $quotedata .= "($field . $data)";
  267.  
  268.   $field = 'gnc:time-no-zone';
  269.   $data = get_quote_time($itemname, $quotehash);
  270.   $quotedata .= " ($field . $data)" if $data;
  271.  
  272.   $field = 'last';
  273.   if (!($$quotehash{$itemname, $field})) {
  274.     $field = 'nav';
  275.   }
  276.   if (!($$quotehash{$itemname, $field})) {
  277.     $field = 'price';
  278.   }
  279.  
  280.   $data = schemify_num($$quotehash{$itemname, $field});
  281.   $quotedata .= " ($field . $data)";
  282.  
  283.   $field = 'currency';
  284.   $data = schemify_string($$quotehash{$itemname, $field});
  285.   $quotedata .= " ($field . $data)";
  286.  
  287.   return "($scmname $quotedata)";
  288. }
  289.  
  290. sub schemify_quotes {
  291.   my($symbols, $quotehash) = @_;
  292.   my $resultstr = "";
  293.   my $sym;
  294.   my $separator = "";
  295.  
  296.   # we have to pass in @$items because Finance::Quote just uses the
  297.   # mangled "$name$field string as the key, so there's no way (I know
  298.   # of) to find out which stocks are in a given quotehash, just given
  299.   # the quotehash.
  300.  
  301.   foreach $sym (@$symbols) {
  302.     $resultstr .= $separator . schemify_quote($sym, $quotehash, 2);
  303.     if(!$separator) { $separator = "\n "; }
  304.   }
  305.   return "($resultstr)\n";
  306. }
  307.  
  308. sub parse_input_line {
  309.  
  310.   # FIXME: we need to rewrite parsing to handle commands modularly.
  311.   # Right now all we do is hard-code "fetch".
  312.  
  313.   my($input) = @_;
  314.   # Have to do this because the perl-mode parser freaks out otherwise.
  315.   my $dq = '"';
  316.   my @symbols;
  317.  
  318.   # Make sure we have an opening ( preceeded only by whitespace.
  319.   # and followed by a one word method name composed of [a-z_]+.
  320.   # Also allow the '.' and '^' characters for stock indices.
  321.   # Kill off the whitespace if we do and grab the command.
  322.   if($input !~ s/^\s*\(\s*([\.\^a-z_]+)\s+//o) { return 0; }
  323.  
  324.   my $quote_method_name = $1;
  325.  
  326.   # Make sure we have an ending ) followed only by whitespace
  327.   # and kill it off if we do...
  328.   if($input !~ s/\s*\)\s*$//o) { return 0; }
  329.  
  330.   while($input) {
  331.     # Items should look like "RHAT"
  332.     # Grab RHAT and delete "RHAT"\s*
  333.     if($input !~ s/^$dq([^$dq]+)$dq\s*//o) { return 0; }
  334.     my $symbol = $1;
  335.     push @symbols, $symbol;
  336.   }
  337.  
  338.   my @result = ($quote_method_name, \@symbols);
  339.   return \@result;
  340. }
  341.  
  342. #---------------------------------------------------------------------------
  343. # Runtime.
  344.  
  345. # Check for and load non-standard modules
  346. check_modules ();
  347.  
  348. # Help Date::Manip on Windows
  349. Date_Init("TZ=UTC") if ($^O eq "MSWin32" && (!$ENV{'TZ'}));
  350.  
  351. # Create a stockquote object.
  352. my $quoter = Finance::Quote->new();
  353. my $prgnam = "gnc-fq-helper";
  354.  
  355. # Disable default currency conversions.
  356. $quoter->set_currency();
  357.  
  358. while(<>) {
  359.  
  360.   my $result = parse_input_line($_);
  361.  
  362.   if(!$result) {
  363.     print STDERR "$prgnam: bad input line ($_)\n";
  364.     exit 1;
  365.   }
  366.  
  367.   my($quote_method_name, $symbols) = @$result;
  368.   my %quote_data;
  369.  
  370.   if($quote_method_name =~ m/^currency$/) {
  371.     my ($from_currency, $to_currency) = @$symbols;
  372.  
  373.     last unless $from_currency;
  374.     last unless $to_currency;
  375.  
  376.     my $price = $quoter->currency($from_currency, $to_currency);
  377.  
  378.     $quote_data{$from_currency, "success"} = defined($price);
  379.     $quote_data{$from_currency, "symbol"} = $from_currency;
  380.     $quote_data{$from_currency, "currency"} = $to_currency;
  381.     $quote_data{$from_currency, "last"} = $price;
  382.  
  383.     my @new_symbols = ($from_currency);
  384.     $symbols = \@new_symbols;
  385.   } else {
  386.     %quote_data = $quoter->fetch($quote_method_name, @$symbols);
  387.   }
  388.  
  389.   if (%quote_data) {
  390.     print schemify_quotes($symbols, \%quote_data);
  391.   } else {
  392.     print "#f\n";
  393.   }
  394.  
  395.   STDOUT->flush();
  396. }
  397.  
  398. exit 0;
  399.  
  400. __END__
  401.  
  402. # Keep this around in case we need to go back to complex per-symbol args.
  403. #
  404. #    while($input) {
  405. #      # Items should look like "RHAT" "EST")
  406. #      # Grab RHAT and delete ("RHAT"\s*
  407. #      if($input !~ s/^\(\s*$dq([^$dq]+)$dq\s*//o) { return 0; }
  408. #      my $symbol = $1;
  409. #      my $timezone;
  410. #      # Now grab EST or #f and delete \s*"EST") or #f)
  411. #      if($input =~ s/^\s*$dq([^$dq]+)$dq\)\s*//o) {
  412. #        $timezone = $1;
  413. #      } else {
  414. #        if($input =~ s/^\s*(\#f)\)\s*//o) {
  415. #          $timezone = 0;
  416. #        } else {
  417. #          return 0;
  418. #        }                
  419. #      }
  420.  
  421. #  sub get_quote_utc {
  422. #    # return the date in utc epoch seconds, using $timezone if specified.
  423. #    my ($item, $timezone, $quotehash) = @_;
  424.  
  425. #    if(!defined($timezone)) { return "failed-conversion"; }
  426.  
  427. #    my $datestr = $$quotehash{$item, 'date'};
  428. #    my $timestr = $$quotehash{$item, 'time'};
  429.  
  430. #    if(!$datestr) {
  431. #      return "failed-conversion";
  432. #    }
  433. #    my $parsestr = $datestr;
  434. #    if($timestr) {
  435. #      $parsestr .= " $timestr";
  436. #    }
  437.  
  438. #    if($timezone) {
  439. #      # Perform a conversion.
  440. #      $parsestr = Date_ConvTZ(ParseDate($parsestr), $timezone, 'UTC');
  441. #    }
  442. #    my $result = UnixDate($parsestr, "%s");
  443. #    if($result !~ /^(\+|-)?\d+$/) {
  444. #      $result = "failed-conversion";
  445. #    }
  446. #    return $result;
  447. #  }
  448.  
  449. ## Local Variables:
  450. ## mode: perl
  451. ## End:
  452.